PROJECT_NAME = libCrashCatch

TARGET = CrashCatch

CONFIG -= qt
CONFIG += c++17
CONFIG += warn_on
CONFIG -= app_bundle

TEMPLATE = lib

DEFINES += $$upper($${TARGET})_LIBRARY
DEFINES += QT_DEPRECATED_WARNINGS

win32:LIBS += -ladvapi32 -lDbgHelp -luser32
unix:LIBS += -ldl -rdynamic

INCLUDEPATH += \
  $$PWD/$$PROJECT_NAME

contains(staticlib, CONFIG): DEFINES += STATIC_LIB

CONFIG(debug, debug|release): BUILD = debug
CONFIG(release, debug|release): BUILD = release

equals(BUILD, "debug"): DEFINES += DEBUG
# equals(BUILD, "debug"): DEFINES += DEBUG_GPB_CLIENTS
equals(BUILD, "release"): DEFINES += QT_NO_DEBUG_OUTPUT

equals(BUILD, "debug"): TARGET = $$join(TARGET,,,d)

DESTDIR     = $$shadowed(./lib)
MOC_DIR     = $$shadowed(./)
OBJECTS_DIR = $$shadowed(./)
RCC_DIR     = $$shadowed(./)
UI_DIR      = $$shadowed(./)

equals(MOC_DIR, "$$PWD") {
    MOC_DIR     = $$PWD/build/$$BUILD
    OBJECTS_DIR = $$PWD/build/$$BUILD
    RCC_DIR     = $$PWD/build/$$BUILD
    UI_DIR      = $$PWD/build/$$BUILD
}

QMAKE_CLEAN += $$DESTDIR

include($${PROJECT_NAME}/$${PROJECT_NAME}.pri)

include(CopyHeaders.pri)